Mean energy

Quantum Mechanics
                      K. Konishi, G. Paffuti

Compute the mean energy for an arbitrary electronic configuration.

ClearAll["Global`*"];
Off[General::spell, General::spell1,InterpolatingFunction::"dmval"];
Off[ClebschGordan::"phy",ClebschGordan::"tri"];

Mean energy

In the text it has been shown that the mean energy for a given electronic configuration can be written as

E = (∑_a)(Subscript[q, a])I[a]+ (∑_a)(((Subscript[q, a])((Subscript[q, a])-1))/2)(∑_(k=0))(Subscript[f, k])[a] (F^k)[a,a] + (∑_(a<b))(Subscript[q, a])(Subscript[q, b]) ((F^0)[a,b]+(∑_(k=0))(Subscript[g, k])[a,b] (G^k)[a,b])

where (Subscript[q, a]),(Subscript[q, b]) are the multiplicities of the orbitals a,b. The notation is

(Subscript[f, 0])[a]=1;     (Subscript[f, k])[a] = - (((2(Subscript[L, a])+1))/((4(Subscript[L, a])+1)))(((({{(Subscript[L, a]), k, (Subscript[L, a])}, {0, 0, 0}})))^2);     (Subscript[g, k])[a,b]=- (1/2)(((({{(Subscript[L, a]), k, (Subscript[L, b])}, {0, 0, 0}})))^2) .

F and G are radial integrals whose expression is not important here (see text). (Subscript[L, a])is the angular moment of orbital a. The sum over k obeys the rules of angular momentum composition and parity conservation, i.e. |(Subscript[L, b])-(Subscript[L, a])| ≤ k ≤ (Subscript[L, a])+(Subscript[L, b]), and the step in k is 2.

f[0,l_] = 1;
f[k_,l_]:= f[k,l]= - ((2l+1)/(4l+1))((ThreeJSymbol[{l,0},{k,0},{l,0}])^2);
g[k_,la_,lb_]:= -(1/2)((ThreeJSymbol[{la,0},{k,0},{lb,0}])^2);

We can easily write 3 functions which gives the 3 contribution to energy, the single particle part, the interaction due to equivalent electrons and the interaction of non equivalent electrons.

First we define the conventional name for orbitals

nameOrbitals = {"s","p","d","f","g","h"};

kin[n_,L_]:= ℐ[ToString[n]<>nameOrbitals[[L+1]]];
equivElectronsEnergy[n_,L_]:= Sum[f[k,L] (F^(ToString[k]))[ToString[n]<>nameOrbitals[[L+1]],ToString[n]<>nameOrbitals[[L+1]]],
{k,0,2L,2}];
nonEquivElectronsEnergy[n1_,L1_,n2_,L2_]:= (F^ToString[0])[ToString[n1]<>nameOrbitals[[L1+1]],
ToString[n2]<>nameOrbitals[[L2+1]]] + 
Sum[g[k,L1,L2] (G^(ToString[k]))[ToString[n1]<>nameOrbitals[[L1+1]],
ToString[n2]<>nameOrbitals[[L2+1]]],
{k,Abs[L2-L1],L2+L1,2}];

We can obtain electron configurations using a Mathematica function as in the following input line

ElementData["Ag", "ElectronConfiguration"]

We can write a function which print the different contribution to mean energy for a given element

meanEnergy[element_]:= Module[{conf,Pqn,Lqn,qa,kinTerm,eqTerm,noneqTerm},
(* If the input is not contained in Mathematica database but is written explicitly this instruction returns the input *)
conf=Quiet[Check[ElementData[element, "ElectronConfiguration"],element]];
(* The principal quantum number *)
Pqn = Flatten[Table[i,{i,1,Length[conf]},{j,1,Length[conf[[i]]]}]];
(* The angular momentum *)
Lqn=Flatten[Table[j-1,{i,1,Length[conf]},{j,1,Length[conf[[i]]]}]];
(* The number of electrons in a given orbital *)
qa = Flatten[conf];
kinTerm = Sum[qa[[i]]kin[Pqn[[i]],Lqn[[i]]],{i,1,Length[qa]}];
eqTerm =  Sum[(1/2)qa[[i]](qa[[i]]-1)equivElectronsEnergy[Pqn[[i]],Lqn[[i]]],{i,1,Length[qa]}];
noneqTerm =  Sum[qa[[i]]qa[[j]]*
nonEquivElectronsEnergy[Pqn[[i]],Lqn[[i]],Pqn[[j]],Lqn[[j]]],
{i,1,Length[qa]},{j,i+1,Length[qa]}];
{kinTerm,eqTerm,noneqTerm}]

Examples

For instance for Carbon

meanEnergy["C"]

We can use as an input also the atomic number

meanEnergy[6]

or the explicit electron configuration

meanEnergy[{{2},{2,2}}]

If excited states are need one must provide the electronic configuration. For example for Li

meanEnergy[3]

For one electron in a p state we can write

conf = {{2},{0,1}};
meanEnergy[conf]

General coefficients

The coefficients (Subscript[f, k]) and (Subscript[g, k])introduced above are particular examples of a more general structure obtained by the integration of three spherical harmonics

c[k,l1,m1,l2,m2]= (Sqrt[((4π)/(2k+1))])∫(Subscript[(SuperStar[Y]), l1m1])(Subscript[Y, l2m2]) (Subscript[Y, km])dΩ

These coefficients can be expressed through Clebsch-Gordan coefficients or the 3-j symbols

c[k,(Subscript[l, 1]),(Subscript[m, 1]),(Subscript[l, 2]),(Subscript[m, 2])]= (((-1))^(Subscript[m, 2]))((Sqrt[(2(Subscript[l, 1])+1)(2(Subscript[l, 2])+1)])/(2k+1))C[(Subscript[l, 1]),-(Subscript[m, 1]);(Subscript[l, 2]),(Subscript[m, 2])|k,(Subscript[m, 2])-(Subscript[m, 1])]C[(Subscript[l, 1]),0;(Subscript[l, 2]),0|k,0];

c[k,(Subscript[l, 1]),(Subscript[m, 1]),(Subscript[l, 2]),(Subscript[m, 2])]= (((-1))^(Subscript[m, 2]))(Sqrt[(2(Subscript[l, 1])+1)(2(Subscript[l, 2])+1)]) (({{(Subscript[l, 1]), (Subscript[l, 2]), k}, {-(Subscript[m, 1]), (Subscript[m, 2]), (Subscript[m, 1])-(Subscript[m, 2])}}))(({{(Subscript[l, 1]), (Subscript[l, 2]), k}, {0, 0, 0}})).

Direct and exchange integrals in the same electronic configuration canbe expressed through these coefficients (see text)

⟨(Subscript[i, α]),(Subscript[j, α])|U|(Subscript[i, β]),(Subscript[j, β])⟩ = (Subscript[δ, (Subscript[s, (Subscript[i, α])])(Subscript[s, (Subscript[i, β])])])(Subscript[δ, (Subscript[s, (Subscript[j, α])])(Subscript[s, (Subscript[j, β])])])(∑_k)(c^k)[(Subscript[ℓ, i])(Subscript[m, (Subscript[i, α])]);(Subscript[ℓ, i])(Subscript[m, (Subscript[i, β])])](c^k)[(Subscript[ℓ, j])(Subscript[m, (Subscript[j, β])]);(Subscript[ℓ, j])(Subscript[m, (Subscript[j, α])])](F^k)[(Subscript[ℓ, i]),(Subscript[ℓ, j])];
⟨(Subscript[i, α]),(Subscript[j, α])|U|(Subscript[j, β]),(Subscript[i, β])⟩ = (Subscript[δ, (Subscript[s, (Subscript[i, α])])(Subscript[s, (Subscript[j, β])])])(Subscript[δ, (Subscript[s, (Subscript[j, α])])(Subscript[s, (Subscript[i, β])])])(∑_k)(c^k)[(Subscript[ℓ, i])(Subscript[m, (Subscript[i, α])]);(Subscript[ℓ, j])(Subscript[m, (Subscript[j, β])])](c^k)[(Subscript[ℓ, j])(Subscript[m, (Subscript[i, β])]);(Subscript[ℓ, j])(Subscript[m, (Subscript[j, α])])](G^k)[(Subscript[ℓ, i]),(Subscript[ℓ, j])];

where F and G are radial integrals.

Let us check these relations in some simple cases.

c[k_,l1_,m1_,l2_,m2_]:= 
Check[(((-1))^m2)(Sqrt[(((2l1+1)(2l2+1))/(((2k+1))^2))])*
ClebschGordan[{l1,-m1},{l2,m2},{k,m2-m1}]*
ClebschGordan[{l1,0},{l2,0},{k,0}],0]

c3J[k_,l1_,m1_,l2_,m2_]:= (((-1))^m1)(Sqrt[(2l1+1)(2l2+1)])*
ThreeJSymbol[{l1,-m1},{l2,m2},{k,m1-m2}]ThreeJSymbol[{l1,0},{l2,0},{k,0}]

cAnalitic[k_,L1_,m1_,L2_,m2_]:= (Sqrt[((4π)/(2k+1))]) *2π*Integrate[Sin[θ](SphericalHarmonicY[L1,m1,θ,0]/.Complex[0,n_]->-Complex[0,n])
SphericalHarmonicY[L2,m2,θ,0]SphericalHarmonicY[k,m1-m2,θ,0],
{θ,0,π}]

L1 = 1; L2 = 2;m1 = 1;m2 = 2; k =1;

{c[k,L1,m1,L2,m2],c3J[k,L1,m1,L2,m2],cAnalitic[k,L1,m1,L2,m2]}

k=3;
{c[k,L1,m1,L2,m2],c3J[k,L1,m1,L2,m2],cAnalitic[k,L1,m1,L2,m2]}