Spherical waves

Quantum Mechanics
 K. Konishi, G. Paffuti

Plot the first few free spherical waves (Subscript[j, L]),(Subscript[n, L]) graphically.   Check how the goodness of the expansion

Exp[i k z] = Exp[i k r Cos[θ]]= (∑_(L=0)^∞)(2L+1)(i^L) (Subscript[j, L])[k r] (Subscript[P, L])[Cos[θ]],

depends on the number of terms kept.

ClearAll["Global`*"];
Off[General::"spell",General::"spell1"];
Needs["PlotLegends`"]

Partial wave analysis of a plane wave

Consider a plane wave ψ = Exp[i k x ], considering the z axis the direction of  k, ψ takes the form Ex[[i k r Cos[θ]], where r is the radial coordinate and θ the polar angle. ψ is invariant under rotation around z axis, it does not depend on the azimuthal and it can be expanded in eigenstates of (L^2) and (Subscript[L, z]), only (Subscript[L, z])= 0 contributing. The spherical harmonic (Subscript[Y, L]^0)(θ,φ) is proportional to a Legendre polinomial in Cos[θ] so we can write

(e^(i k r cos(θ)))=(∑_(L=0)^∞)(Subscript[a, L])(r) (Subscript[P, L])(cos(θ))

The functions (Subscript[a, L])[r] turns out to be proportional to Bessel functions of order n+1/2, n ∈ ℕ. These functions are called also Spherical Bessel functions. There are two types of Bessel functions BesselJ[ν,x] and BesselY{ν,x] and correspondingly two spherical Bessel functions usually written (Subscript[j, L])[x] (Subscript[y, L])[x]. Below we will use the notation jB and yB

Properties of spherical Bessel functions

jB[L_,r_]:=(Sqrt[(π/(2r))])BesselJ[L+(1/2),r]; yB[L_,r_]:=(Sqrt[(π/(2r))])BesselY[L+(1/2),r];

The spherical Bessel functions are also defined as Mathematica functions, here we adopt their explicit definition.

The first is regular on the origin, the second one singular. In particular jB[L,0] = (Subscript[δ, L,0]). In the plot the dashed line is yB[L, r]:

TabView[Table[L-> Plot[{jB[L,r],yB[L,r]},{r,0.01,5 (L+2)},
PlotRange->If[L== 0, {Automatic,{-1,1}},{Automatic,Automatic}],
PlotStyle->{RGBColor[0,0,0],{RGBColor[1,0,0],Dashing[{0.015`,0.015`}]}}],
{L,0,6}]]

Connections with other functions

Functions jB and yB are in effect almost trigonometric functions in disguise

(Subscript[j, L])[x]= (((-1))^L) (x^L)((( (1/x)(∂_x)))^L) ((Sin[x])/x);          (Subscript[y, L])[x]= (((-1))^(L+1)) (x^L)((( (1/x)(∂_x)))^L) ((Cos[x])/x);

ex:

jB[3,x]

Let us check this for the first few value of L

disguiseJ[L_,x_]:=(((-1))^L)x^L Nest[(1/x) (∂_x)#& ,Sin[x]/x,L]
disguiseY[L_,x_]:=(((-1))^(L+1))x^L Nest[(1/x) (∂_x)#& ,Cos[x]/x,L]

Table[Simplify[disguiseJ[L,x]- jB[L,x],x>0],{L,0,4}]

Table[Simplify[disguiseY[L,x]- yB[L,x],x>0],{L,0,4}]

Asymptotic behaviour

From asymptotic expansion of Bessel functions:

(Subscript[J, ν])[x]∼ (Sqrt[(2/(π x))])Cos[ x - (π/2)ν - (π/4)];   (Subscript[Y, ν])[x] ∼ (Sqrt[(2/(π x))])Sin[ x - (π/2)ν - (π/4)];

or directly from (2)

(Subscript[j, L])[x] ∼ (1/x)Cos[ x - (π/2)(L+(1/2)) - (π/4)] =  (1/x)Sin[ x - (π/2)L]
  (Subscript[y, L])[x] ∼ (1/x)Sin[ x - (π/2)(L+(1/2)) - (π/4)]= - (1/x)Cos[ x - (π/2)L]

Let us note that expansion () can be directly obtained by Mathematica

Off[Series::"esss"];
Normal[Series[BesselJ[ν,x],{x,∞,0}]]

Simplify[Simplify[Normal[Series[BesselY[ν,x],{x,∞,0}]],{0<ν<1}],ComplexityFunction->(Count[{#1},_Complex,∞]&)]

On[Series::"esss"];

this last expression is easily seen to be equal to (). The complicated instruction above is to avoid  a limiting process needed for integers ν. The expansion (4) is crucial for applications to Physics.

Partial wave expansion

The explicit form of partial wave expansion is

(e^(i k r cos(θ)))=(∑_(L=0)^∞)(i^L) (Subscript[ (2L+1) (Subscript[j, L])[kr] P, L])(cos(θ))

Only the non singular  (Subscript[j, L]) functions appears in (). By multiplication for (Subscript[P, m])(cos(θ)) and remembering that

(∫_0^π)(Subscript[P, L])(cos(θ)) (Subscript[P, M])(cos(θ)) sin(θ)dθ = (∫_(-1)^1)(Subscript[P, L])(x) (Subscript[P, M])(x)dx = (2/(2L+1))(Subscript[δ, LM])

to check () we have to verify

(∫_0^π)(e^(i α cos(θ))) (Subscript[P, L])(cos(θ)) sin(θ)dθ = (∫_(-1)^1)(e^(i α t)) (Subscript[P, L])(t)dt = (i^L) 2 (Subscript[j, L])[α].

In effect:

Table[Simplify[Integrate[Exp[I α t] LegendreP[L,t] ,{t,-1,1},Assumptions-> α>0] - 2 (I^L)jB[L,α],α>0],{L,0,3}]

Accuracy

A finite sum must be considered in numerical applications. Let us define (we put  kr = ρ → r )

approximateSum[Lmax_,r_,θ_]:= Sum[(I^L)(2L+1) jB[L,r] LegendreP[L,Cos[θ]],{L,0,Lmax}];

r0 = 9; Lmax = 10;

Plot[{Cos[r0 Cos[θ]],Re[approximateSum[Lmax,r0,θ]]},{θ,0,π},PlotStyle->{{RGBColor[1,0,0],Dashing[{0.015`,0.015`}]},{}},PlotLabel->"r = 9",PlotLegend->{"exact","approx"},LegendPosition->{1.1`,-0.5`}]

It is quite evident that the approximation is good except for a narrow cone in the forward and backward directions.

For fixed θ

θ0 = π/6; Lmax = 10;

Plot[{Cos[r Cos[θ0]],Re[approximateSum[Lmax,r,θ0]]},{r,0,20},PlotStyle->{{RGBColor[1,0,0],Dashing[{0.015`,0.015`}]},{}},PlotLabel->"θ = π/6",PlotLegend->{"exact","approx"},LegendPosition->{1.1`,-0.5`}]

We see that the approximation holds up to r such that k r ∼ Lmax, as expected ( angular momenum = momentum × distance ). Clearly the approximation goes better for higher Lmax

Lmax = 20;

Plot[{Cos[r Cos[θ0]],Re[approximateSum[Lmax,r,θ0]]},{r,0,30},PlotStyle->{{RGBColor[1,0,0],Dashing[{0.015`,0.015`}]},{}},PlotLabel->"θ = π/6",PlotLegend->{"exact","approx"},LegendPosition->{1.1`,-0.5`}]

Some observations on the large r limit

The large r limit of the sum () is quite delicate. In fact  the limit does not exist for the left hand side. The asymptotic expansion of the Bessel functions is valid for r ≫ ν (the order) so strictly speaking it is not possible to interchange the summation with the large r. If we do this and apply eq() we have

(∑_(L=0)^∞)(I^L) (2 l+1)(1/(2(Sqrt[k r]) )) ((E^(I (-((π L)/2)+k r-(π/4))))+(E^(-I (-((π L)/2)+k r-(π/4))))) (Subscript[P, L])(cos(θ)) =
(1/(2(Sqrt[k r]))) (∑_(L=0)^∞) (2l+1)((E^(I (k r-(π/4))))+ (((-1))^L)(E^(-I (k r-(π/4)))))(Subscript[P, L])(cos(θ));

Formally

4δ(1-Cos[θ]) = (∑_(L=0)^∞)(2L+1) (Subscript[P, L])(cos(θ));  4δ(1+Cos[θ]) = (∑_(L=0)^∞)(2L+1)(((-1))^L) (Subscript[P, L])(cos(θ)).

The first relation is verified by multiplication by Sin[θ] and integrating, using formally (∫_0^(a>0))δ[x]dx = 1/2 (δ assumed as an even function). The second relation follows by changing θ → θ+π and from (Subscript[P, L])[-x] = (((-1))^L)(Subscript[P, L])[x]. So formally

Exp[I k r Cos[θ]] (Underscript[⟶, r→∞]) (2/(Sqrt[k r]))((E^(I (k r-(π/4))))δ(1-Cos[θ]) + (E^(-I (k r-(π/4))))δ(1+Cos[θ]) ).

A very singular limit indeed!

Vice versa for fixed L, i.e. in quantum mechanics language if we fix our attention to a fixed angular momentum, the asymptotic expression (4), but now only for k r ≫ L.